move kcl.py to this repo (#5587)

* ci for kcl-python-bindings Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * bettter concurrency Signed-off-by: Jess Frazelle <github@jessfraz.com> * cleanup files Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * updaets Signed-off-by: Jess Frazelle <github@jessfraz.com> * updaets Signed-off-by: Jess Frazelle <github@jessfraz.com> * updaets Signed-off-by: Jess Frazelle <github@jessfraz.com> * updaets Signed-off-by: Jess Frazelle <github@jessfraz.com> * format Signed-off-by: Jess Frazelle <github@jessfraz.com> * format Signed-off-by: Jess Frazelle <github@jessfraz.com> --------- Signed-off-by: Jess Frazelle <github@jessfraz.com>
2025-03-01 16:38:25 -08:00
parent 66f3500ca9
commit a4db302174
30 changed files with 1541 additions and 14 deletions
--- a/rust/kcl-python-bindings/files/box_with_linter_errors.kcl
+++ b/rust/kcl-python-bindings/files/box_with_linter_errors.kcl
@ -0,0 +1,14 @@
+// A 25x25x50 box
+
+const box_width = 25
+const box_depth = 25
+const box_height = 50
+
+const box_sketch = startSketchOn('XY')
+  |> startProfileAt([0, 0], %)
+  |> xLine(box_width, %, $line1)
+  |> yLine(box_depth, %, $line2)
+  |> xLineTo(profileStartX(%), %, $line3)
+  |> close(%, $line4)
+
+const box3D = extrude(box_sketch, length = box_height)
--- a/rust/kcl-python-bindings/files/parse_file_error/main.kcl
+++ b/rust/kcl-python-bindings/files/parse_file_error/main.kcl
@ -0,0 +1 @@
+import thing from 'thing.kcl'
--- a/rust/kcl-python-bindings/files/parse_file_error/thing.kcl
+++ b/rust/kcl-python-bindings/files/parse_file_error/thing.kcl
@ -0,0 +1 @@
+lksjndflsskjfnak;jfna##
--- a/rust/kcl-python-bindings/files/walkie-talkie/antenna.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/antenna.kcl
@ -0,0 +1,50 @@
+// Antenna
+
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+
+// import constants
+import height, width, antennaBaseWidth, antennaBaseHeight, antennaTopWidth, antennaTopHeight from "globals.kcl"
+
+// Calculate the origin
+origin = [-width / 2 + .45, -0.10]
+
+// Create the antenna
+antennaX = origin[0]
+antennaY = origin[1]
+
+antennaPlane = {
+  plane = {
+    origin = { x = 0, y = 0, z = height / 2 },
+    xAxis = { x = 1, y = 0, z = 0 },
+    yAxis = { x = 0, y = 1, z = 0 },
+    zAxis = { x = 0, y = 0, z = 1 }
+  }
+}
+
+// Create the antenna base sketch
+sketch001 = startSketchOn(antennaPlane)
+  |> startProfileAt([origin[0], origin[1]], %)
+  |> line(end = [antennaBaseWidth, 0])
+  |> line(end = [0, -antennaBaseHeight])
+  |> line(end = [-antennaBaseWidth, 0])
+  |> close()
+
+// Create the antenna top sketch
+loftPlane = offsetPlane('XY', offset = height / 2 + 3)
+
+sketch002 = startSketchOn(loftPlane)
+  |> startProfileAt([
+       origin[0] + (antennaBaseWidth - antennaTopWidth) / 2,
+       origin[1] - ((antennaBaseHeight - antennaTopHeight) / 2)
+     ], %)
+  |> xLine(antennaTopWidth, %)
+  |> yLine(-antennaTopHeight, %)
+  |> xLine(-antennaTopWidth, %)
+  |> close()
+
+// Create the antenna using a loft
+loft([sketch001, sketch002])
+  |> appearance(color = "#000000")
--- a/rust/kcl-python-bindings/files/walkie-talkie/body.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/body.kcl
@ -0,0 +1,80 @@
+// Walkie talkie body
+
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+
+// Import constants
+import height, width, thickness, chamferLength, offset, screenWidth, screenHeight, screenYPosition, screenDepth, speakerBoxWidth, speakerBoxHeight from "globals.kcl"
+
+bodySketch = startSketchOn('XZ')
+  |> startProfileAt([-width / 2, height / 2], %)
+  |> xLine(width, %, $chamfer1)
+  |> yLine(-height, %, $chamfer2)
+  |> xLine(-width, %, $chamfer3)
+  |> close(tag = $chamfer4)
+bodyExtrude = extrude(bodySketch, length = thickness)
+  |> chamfer(
+       length = chamferLength,
+       tags = [
+         getNextAdjacentEdge(chamfer1),
+         getNextAdjacentEdge(chamfer2),
+         getNextAdjacentEdge(chamfer3),
+         getNextAdjacentEdge(chamfer4)
+       ]
+     )
+
+// Define the offset for the indentation
+sketch002 = startSketchOn(bodyExtrude, 'END')
+  |> startProfileAt([
+       -width / 2 + offset,
+       height / 2 - (chamferLength + offset / 2 * cos(toRadians(45)))
+     ], %)
+  |> angledLineToY({ angle = 45, to = height / 2 - offset }, %)
+  |> line(endAbsolute = [
+       width / 2 - (chamferLength + offset / 2 * cos(toRadians(45))),
+       height / 2 - offset
+     ])
+  |> angledLineToX({ angle = -45, to = width / 2 - offset }, %)
+  |> line(endAbsolute = [
+       width / 2 - offset,
+       -(height / 2 - (chamferLength + offset / 2 * cos(toRadians(45))))
+     ])
+  |> angledLineToY({
+       angle = -135,
+       to = -height / 2 + offset
+     }, %)
+  |> line(endAbsolute = [
+       -(width / 2 - (chamferLength + offset / 2 * cos(toRadians(45)))),
+       -height / 2 + offset
+     ])
+  |> angledLineToX({
+       angle = -225,
+       to = -width / 2 + offset
+     }, %)
+  |> close()
+extrude002 = extrude(sketch002, length = -0.0625)
+
+// Create the pocket for the screen
+sketch003 = startSketchOn(extrude002, 'start')
+  |> startProfileAt([-screenWidth / 2, screenYPosition], %)
+  |> xLine(screenWidth, %, $seg01)
+  |> yLine(-screenHeight, %)
+  |> xLine(-segLen(seg01), %)
+  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
+  |> close()
+extrude003 = extrude(sketch003, length = screenDepth)
+
+// Create the speaker box
+sketch004 = startSketchOn(extrude002, 'start')
+  |> startProfileAt([-1.25 / 2, -.125], %)
+  |> xLine(speakerBoxWidth, %)
+  |> yLine(-speakerBoxHeight, %)
+  |> xLine(-speakerBoxWidth, %)
+  |> close()
+extrude(sketch004, length = -.5)
+  |> appearance(
+    color = "#277bb0",
+  )
+
--- a/rust/kcl-python-bindings/files/walkie-talkie/button.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/button.kcl
@ -0,0 +1,38 @@
+// Walkie Talkie button
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+// Import constants
+import screenHeight, buttonWidth, tolerance, buttonHeight, buttonThickness from 'globals.kcl'
+
+
+// Create a function for the button
+export fn button(origin, rotation, plane) {
+  buttonSketch = startSketchOn(plane)
+    |> startProfileAt([origin[0], origin[1]], %)
+    |> angledLine({
+         angle = 180 + rotation,
+         length = buttonWidth
+       }, %, $tag1)
+    |> angledLine({
+         angle = 270 + rotation,
+         length = buttonHeight
+       }, %, $tag2)
+    |> angledLine({
+         angle = 0 + rotation,
+         length = buttonWidth
+       }, %)
+    |> close()
+  buttonExtrude = extrude(buttonSketch, length = buttonThickness)
+    |> chamfer(
+         length = .050,
+         tags = [
+           getNextAdjacentEdge(tag1),
+           getNextAdjacentEdge(tag2)
+         ]
+       )
+     |> appearance(color = "#ff0000")
+
+  return buttonExtrude
+}
--- a/rust/kcl-python-bindings/files/walkie-talkie/case.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/case.kcl
@ -0,0 +1,85 @@
+// Walkie talkie case
+
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+
+// Import constants and Zoo logo
+import width, height, chamferLength, offset, screenWidth, screenHeight, screenYPosition, screenDepth, speakerBoxWidth, speakerBoxHeight, squareHoleSideLength, caseTolerance from "globals.kcl"
+import zLogo, oLogo, oLogo2 from "zoo-logo.kcl"
+
+plane = offsetPlane("XZ", offset = 1)
+
+fn screenHole(sketchStart) {
+  sketch006 = startSketchOn(sketchStart)
+    |> startProfileAt([-screenWidth / 2, screenYPosition], %)
+    |> xLine(screenWidth, %)
+    |> yLine(-screenHeight, %)
+    |> xLine(-screenWidth, %)
+    |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
+    |> close()
+  return sketch006
+}
+
+fn squareHolePattern(plane, x, y) {
+  fn transformX(i) {
+    return { translate = [.125 * i, 0] }
+  }
+  fn transformY(i) {
+    return { translate = [0, -.125 * i] }
+  }
+  squareHolePatternSketch = startSketchOn(plane)
+    |> startProfileAt([-x, -y], %)
+    |> line(end = [squareHoleSideLength / 2, 0])
+    |> line(end = [0, -squareHoleSideLength / 2])
+    |> line(end = [-squareHoleSideLength / 2, 0])
+    |> close()
+    |> patternTransform2d(instances = 13, transform = transformX)
+    |> patternTransform2d(instances = 11, transform = transformY)
+  return squareHolePatternSketch
+}
+sketch005 = startSketchOn(offsetPlane("XZ", offset = 1))
+  |> startProfileAt([
+       -width / 2 + offset + caseTolerance,
+       height / 2 - (chamferLength + (offset + caseTolerance) / 2 * cos(toRadians(45)))
+     ], %)
+  |> angledLineToY({
+       angle = 45,
+       to = height / 2 - (offset + caseTolerance)
+     }, %)
+  |> line(endAbsolute = [
+       width / 2 - (chamferLength + (offset + caseTolerance) / 2 * cos(toRadians(45))),
+       height / 2 - (offset + caseTolerance)
+     ])
+  |> angledLineToX({
+       angle = -45,
+       to = width / 2 - (offset + caseTolerance)
+     }, %)
+  |> line(endAbsolute = [
+       width / 2 - (offset + caseTolerance),
+       -(height / 2 - (chamferLength + (offset + caseTolerance) / 2 * cos(toRadians(45))))
+     ])
+  |> angledLineToY({
+       angle = -135,
+       to = -height / 2 + offset + caseTolerance
+     }, %)
+  |> line(endAbsolute = [
+       -(width / 2 - (chamferLength + (offset + caseTolerance) / 2 * cos(toRadians(45)))),
+       -height / 2 + offset + caseTolerance
+     ])
+  |> angledLineToX({
+       angle = -225,
+       to = -width / 2 + offset + caseTolerance
+     }, %)
+  |> close()
+  |> hole(screenHole(plane), %)
+  |> hole(squareHolePattern(plane, .75, .125), %)
+  |> hole(zLogo(plane, [-.30, -1.825], .20), %)
+  |> hole(oLogo(plane, [-.075, -1.825], .20), %)
+  |> hole(oLogo2(plane, [-.075, -1.825], .20), %)
+  |> hole(oLogo(plane, [.175, -1.825], .20), %)
+  |> hole(oLogo2(plane, [.175, -1.825], .20), %)
+
+extrude(sketch005, length = -0.0625)
+  |> appearance(color = '#D0FF01', metalness = 0, roughness = 50)
--- a/rust/kcl-python-bindings/files/walkie-talkie/globals.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/globals.kcl
@ -0,0 +1,42 @@
+// Global constants for the walkie talkie
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+// body
+export height = 4
+export width = 2.5
+export thickness = 1
+export chamferLength = .325
+export offset = .125
+export screenWidth = 1.75
+export screenHeight = 1
+export screenYPosition = height / 2 - 0.75
+export screenDepth = -.0625
+export speakerBoxWidth = 1.25
+export speakerBoxHeight = 1.25
+
+// antenna
+export antennaBaseWidth = .5
+export antennaBaseHeight = .25
+export antennaTopWidth = .30
+export antennaTopHeight = .05
+
+// button
+export buttonWidth = .15
+export tolerance = 0.020
+export buttonHeight = screenHeight / 2 - tolerance
+export buttonThickness = .040
+
+// case
+export squareHoleSideLength = 0.0625
+export caseTolerance = 0.010
+
+// knob
+export knobDiameter = .5
+export knobHeight = .25
+export knobRadius = 0.050
+
+// talk-button
+export talkButtonSideLength = 0.5
+export talkButtonHeight = 0.050
--- a/rust/kcl-python-bindings/files/walkie-talkie/knob.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/knob.kcl
@ -0,0 +1,38 @@
+// Walkie talkie knob
+
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+
+// Import constants
+import width, thickness, height, knobDiameter, knobHeight, knobRadius from "globals.kcl"
+
+// Define the plane for the knob
+knobPlane = {
+  plane = {
+    origin = {
+      x = width / 2 - 0.70,
+      y = -thickness / 2,
+      z = height / 2
+    },
+    xAxis = { x = 1, y = 0, z = 0 },
+    yAxis = { x = 0, y = 0, z = 1 },
+    zAxis = { x = 0, y = 1, z = 0 }
+  }
+}
+
+// Create the knob sketch and revolve
+startSketchOn(knobPlane)
+  |> startProfileAt([0.0001, 0], %)
+  |> xLine(knobDiameter / 2, %)
+  |> yLine(knobHeight - 0.05, %)
+  |> arc({
+       angleStart = 0,
+       angleEnd = 90,
+       radius = .05
+     }, %)
+  |> xLineTo(0.0001, %)
+  |> close()
+  |> revolve({ axis = "Y" }, %)
+  |> appearance(color = '#D0FF01', metalness = 90, roughness = 50)
--- a/rust/kcl-python-bindings/files/walkie-talkie/main.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/main.kcl
@ -0,0 +1,50 @@
+// Walkie Talkie
+// A portable, handheld two-way radio device that allows users to communicate wirelessly over short to medium distances. It operates on specific radio frequencies and features a push-to-talk button for transmitting messages, making it ideal for quick and reliable communication in outdoor, work, or emergency settings.
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+// Import parts and constants
+import 'body.kcl'
+import 'antenna.kcl'
+import 'case.kcl'
+import 'talk-button.kcl' as talkButton
+import 'knob.kcl'
+import button from "button.kcl"
+import width, height, thickness, screenWidth, screenHeight, screenYPosition, tolerance from "globals.kcl"
+
+// Import the body
+body
+
+// Import the case
+case
+
+// Import the antenna
+antenna
+
+// Import the buttons
+button([
+  -(screenWidth / 2 + tolerance),
+  screenYPosition
+], 0, offsetPlane("XZ", offset = thickness))
+button([
+  -(screenWidth / 2 + tolerance),
+  screenYPosition - (screenHeight / 2)
+], 0, offsetPlane("XZ", offset = thickness))
+button([
+  screenWidth / 2 + tolerance,
+  screenYPosition - screenHeight
+], 180, offsetPlane("XZ", offset = thickness))
+button([
+  screenWidth / 2 + tolerance,
+  screenYPosition - (screenHeight / 2)
+], 180, offsetPlane("XZ", offset = thickness))
+
+// Import the talk button
+talkButton
+  
+// Import the frequency knob
+knob
+  
+
+
--- a/rust/kcl-python-bindings/files/walkie-talkie/talk-button.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/talk-button.kcl
@ -0,0 +1,46 @@
+// Walkie talkie talk button
+
+
+// Set units
+@settings(defaultLengthUnit = in)
+
+
+// Import constants
+import width, thickness, talkButtonSideLength, talkButtonHeight from "globals.kcl"
+
+talkButtonPlane = {
+  plane = {
+    origin = {
+      x = width / 2,
+      y = -thickness / 2,
+      z = .5
+    },
+    xAxis = { x = 0, y = 1, z = 0 },
+    yAxis = { x = 0, y = 0, z = 1 },
+    zAxis = { x = 1, y = 0, z = 0 }
+  }
+}
+
+// Create the talk button sketch
+talkButtonSketch = startSketchOn(talkButtonPlane)
+  |> startProfileAt([
+       -talkButtonSideLength / 2,
+       talkButtonSideLength / 2
+     ], %)
+  |> xLine(talkButtonSideLength, %, $tag1)
+  |> yLine(-talkButtonSideLength, %, $tag2)
+  |> xLine(-talkButtonSideLength, %, $tag3)
+  |> close(tag = $tag4)
+
+// Create the talk button and apply fillets
+extrude(talkButtonSketch, length = talkButtonHeight)
+  |> fillet(
+       radius = 0.050,
+       tags = [
+         getNextAdjacentEdge(tag1),
+         getNextAdjacentEdge(tag2),
+         getNextAdjacentEdge(tag3),
+         getNextAdjacentEdge(tag4)
+       ]
+     )
+  |> appearance(color = '#D0FF01', metalness = 90, roughness = 90)
--- a/rust/kcl-python-bindings/files/walkie-talkie/zoo-logo.kcl
+++ b/rust/kcl-python-bindings/files/walkie-talkie/zoo-logo.kcl
@ -0,0 +1,83 @@
+// Zoo logo
+
+// Define a function to draw the ZOO "Z"
+export fn zLogo(surface, origin, scale) {
+  zSketch = surface
+    |> startProfileAt([
+         0 + origin[0],
+         0.15 * scale + origin[1]
+       ], %)
+    |> yLine(-0.15 * scale, %)
+    |> xLine(0.15 * scale, %)
+    |> angledLineToX({
+         angle = 47.15,
+         to = 0.3 * scale + origin[0]
+       }, %, $seg1)
+    |> yLineTo(0 + origin[1], %, $seg3)
+    |> xLine(0.63 * scale, %)
+    |> yLine(0.225 * scale, %)
+    |> xLine(-0.57 * scale, %)
+    |> angledLineToX({
+         angle = 47.15,
+         to = 0.93 * scale + origin[0]
+       }, %)
+    |> yLine(0.15 * scale, %)
+    |> xLine(-0.15 * scale, %)
+    |> angledLine({
+         angle = 47.15,
+         length = -segLen(seg1)
+       }, %, $seg2)
+    |> yLine(segLen(seg3), %)
+    |> xLineTo(0 + origin[0], %)
+    |> yLine(-0.225 * scale, %)
+    |> angledLineThatIntersects({
+         angle = 0,
+         intersectTag = seg2,
+         offset = 0
+       }, %)
+    |> close()
+  return zSketch
+}
+
+// Define a function to draw the ZOO "O"
+export fn oLogo(surface, origin, scale) {
+  oSketch001 = surface
+    |> startProfileAt([
+         .788 * scale + origin[0],
+         .921 * scale + origin[1]
+       ], %)
+    |> arc({
+         angleStart = 47.15 + 6,
+         angleEnd = 47.15 - 6 + 180,
+         radius = .525 * scale
+       }, %)
+    |> angledLine({ angle = 47.15, length = .24 * scale }, %)
+    |> arc({
+         angleStart = 47.15 - 11 + 180,
+         angleEnd = 47.15 + 11,
+         radius = .288 * scale
+       }, %)
+    |> close()
+  return oSketch001
+}
+
+export fn oLogo2(surface, origin, scale) {
+  oSketch002 = surface
+    |> startProfileAt([
+         .16 * scale + origin[0],
+         .079 * scale + origin[1]
+       ], %)
+    |> arc({
+         angleStart = 47.15 + 6 - 180,
+         angleEnd = 47.15 - 6,
+         radius = .525 * scale
+       }, %)
+    |> angledLine({ angle = 47.15, length = -.24 * scale }, %)
+    |> arc({
+         angleStart = 47.15 - 11,
+         angleEnd = 47.15 + 11 - 180,
+         radius = .288 * scale
+       }, %)
+    |> close()
+  return oSketch002
+}