656eb0abec
* update all kcl-samples * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * fixes Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * updates Signed-off-by: Jess Frazelle <github@jessfraz.com> * Update kcl-samples simulation test output --------- Signed-off-by: Jess Frazelle <github@jessfraz.com> Co-authored-by: Jess Frazelle <jessfraz@users.noreply.github.com> Co-authored-by: Jess Frazelle <github@jessfraz.com> Co-authored-by: github-actions[bot] <github-actions[bot]@users.noreply.github.com>
79 lines
2.5 KiB
Plaintext
79 lines
2.5 KiB
Plaintext
// Walkie Talkie Body
|
|
// The main body of the walkie talkie assembly
|
|
|
|
// Set units
|
|
@settings(defaultLengthUnit = in)
|
|
|
|
// Import parameters
|
|
import height, width, thickness, chamferLength, offset, screenWidth, screenHeight, screenYPosition, screenDepth, speakerBoxWidth, speakerBoxHeight from "parameters.kcl"
|
|
|
|
// Sketch and extrude the body of the walkie talkie
|
|
body = startSketchOn(XZ)
|
|
|> startProfileAt([-width / 2, height / 2], %)
|
|
|> xLine(length = width, tag = $chamfer1)
|
|
|> yLine(length = -height, tag = $chamfer2)
|
|
|> xLine(length = -width, tag = $chamfer3)
|
|
|> close(tag = $chamfer4)
|
|
|> extrude(%, length = thickness)
|
|
|> chamfer(
|
|
length = chamferLength,
|
|
tags = [
|
|
getNextAdjacentEdge(chamfer1),
|
|
getNextAdjacentEdge(chamfer2),
|
|
getNextAdjacentEdge(chamfer3),
|
|
getNextAdjacentEdge(chamfer4)
|
|
],
|
|
)
|
|
|
|
// Cut out the indentation for the case
|
|
caseIndentSketch = startSketchOn(body, 'END')
|
|
|> startProfileAt([
|
|
-width / 2 + offset,
|
|
height / 2 - (chamferLength + offset / 2 * cos(toRadians(45)))
|
|
], %)
|
|
|> angledLineToY({ angle = 45, to = height / 2 - offset }, %)
|
|
|> line(endAbsolute = [
|
|
width / 2 - (chamferLength + offset / 2 * cos(toRadians(45))),
|
|
height / 2 - offset
|
|
])
|
|
|> angledLineToX({ angle = -45, to = width / 2 - offset }, %)
|
|
|> line(endAbsolute = [
|
|
width / 2 - offset,
|
|
-(height / 2 - (chamferLength + offset / 2 * cos(toRadians(45))))
|
|
])
|
|
|> angledLineToY({
|
|
angle = -135,
|
|
to = -height / 2 + offset
|
|
}, %)
|
|
|> line(endAbsolute = [
|
|
-(width / 2 - (chamferLength + offset / 2 * cos(toRadians(45)))),
|
|
-height / 2 + offset
|
|
])
|
|
|> angledLineToX({
|
|
angle = -225,
|
|
to = -width / 2 + offset
|
|
}, %)
|
|
|> close()
|
|
extrude002 = extrude(caseIndentSketch, length = -0.0625)
|
|
|
|
// Create the pocket for the screen
|
|
screenCutout = startSketchOn(extrude002, 'start')
|
|
|> startProfileAt([-screenWidth / 2, screenYPosition], %)
|
|
|> xLine(length = screenWidth, tag = $seg01)
|
|
|> yLine(length = -screenHeight)
|
|
|> xLine(length = -segLen(seg01))
|
|
|> line(endAbsolute = [profileStartX(%), profileStartY(%)])
|
|
|> close()
|
|
extrude003 = extrude(screenCutout, length = screenDepth)
|
|
|
|
// Create the speaker box
|
|
speakerBox = startSketchOn(extrude002, 'start')
|
|
|> startProfileAt([-1.25 / 2, -.125], %)
|
|
|> xLine(length = speakerBoxWidth)
|
|
|> yLine(length = -speakerBoxHeight)
|
|
|> xLine(length = -speakerBoxWidth)
|
|
|> close()
|
|
|
|
extrude(speakerBox, length = -.5)
|
|
|> appearance(color = "#277bb0")
|